home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
TPUG - Toronto PET Users Group
/
TPUG Users Group CD
/
TPUG Users Group CD.iso
/
CRS
/
crs03.d81
/
ba_v6_2.sda
/
MAILING LABELS
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2009-10-10
|
5KB
|
165 lines
10 POKE53280,0:POKE53281,0:PRINTCHR$(142)
12 CLR:OPEN15,8,15:CR$=CHR$(13):QO$=CHR$(34):POKE788,52:POKE792,193
14 R$=" RETURN [146][158]":Y$="(Y[158]/N[158])":B$="":C$="":E$="[145][145][145][145][145][145][145][145][145][145][145]"
16 LH$="[151] [195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195][195]"
18 K$="[158] USE UP [158][146] OR DOWN [158][146] TO CHOOSE :":CD$="[147]"+B$+C$
20 BL$=" ":S7$=" ":SP$=BL$+BL$
22 AN=1:UP$="[145]":DN$="":C1$="":C2$="[154]"
24 DIML6$(20),L1$(20),L2$(20),L3$(20),L4$(20),L5$(20):GOTO126
26 LL=34:PRINT" >";
28 OPEN9,0:AN$="":BN$="":POKE204,0
30 GET#9,BN$:IFBN$=""THEN30
32 IFBN$=CHR$(13)THENBN$="":CLOSE9:PRINT" ":POKE204,1:RETURN
34 IFBN$=""ORBN$="[157]"ORBN$="[145]"ORBN$=""THENGOTO30
36 IFBN$=""ORBN$="[147]"ORBN$=CHR$(34)THEN30
38 IFLEN(AN$)=LLTHENPRINT" ":PRINT"";LL;"LETTER LIMIT.":BN$=CHR$(13):GOTO32
40 IFAN$=""ANDBN$=CHR$(20)THEN30
42 IFBN$=CHR$(20)THENPRINT" [157][157] [157]";:AN$=LEFT$(AN$,LEN(AN$)-1):GOTO30
44 AN$=AN$+BN$:PRINTBN$;:GOTO30
46 INPUT#15,EN,EM$,ET,ES
48 IF EN=0 THEN RETURN
50 IFNF=1THENNF=0:RETURN
52 PRINT"[147]";B$;B$;" *** ERROR ON DISK *** [146]":PRINTEN;" ";EM$;" ";ET;" ";ES
54 PRINT" DOS ERROR MESSAGE # "EN
56 PRINT"[158] (PROGRAM WILL CONTINUE IN A MOMENT)"
58 CLOSE8:FORT=1TO12345:NEXTT:POKE64,206:GOTO106
60 PRINTK$"[145]"
62 POKE198,0:FORX=1TOMN:PRINTDN$;S7$;C1$;SL$(X):NEXTX
64 PRINT"[158] PRESS "R$" TO ENTER SELECTION.[145]"
66 PRINT"";C5$;S7$;C2$;SL$(1)
68 GETAN$:IFAN$<>""THEN80
70 JV=PEEK(56320):FR=JVAND16:JV=15-(JVAND15)
72 IFJV=1THENAN$=CHR$(145):FORT=1TO100:NEXTT:GOTO80
74 IFJV=2THENAN$=CHR$(17):FORT=1TO100:NEXTT:GOTO80
76 IFFR<>16THENAN$=CHR$(13):FORT=1TO350:NEXTT:GOTO80
78 GOTO68
80 IFAN$=CHR$(13)THENAN$=STR$(AN):RETURN
82 IFAN$=CHR$(145)ORAN$=CHR$(29)THEN88
84 IFAN$=CHR$(17)THEN96
86 GOTO68
88 LN=AN:AN=AN-1:IFAN=0THENAN=MN
90 PRINT"[145]";S7$;C1$;SL$(LN)
92 IFLN=1THENPRINTC4$;S7$;C2$;SL$(AN):GOTO68
94 PRINTUP$;"[145][145]";S7$;C2$;SL$(AN):GOTO68
96 LN=AN:AN=AN+1:IFAN=MN+1THENAN=1
98 PRINT"[145]";S7$;C1$;SL$(LN)
100 IFLN=MNTHENPRINTC3$;S7$;C2$;SL$(AN):GOTO68
102 PRINTDN$;S7$;C2$;SL$(AN):GOTO68
104 Q$=CHR$(34):LJ$=" [155] [145]":OPEN4,4
106 PL$="[147][154] P R I N T L A B E L S ":PRINTPL$:AN=1
108 FORX=1TO6:NN$(X)="":NEXTX:PRINTK$
110 C3$="":FORX=1TOMN:C3$=C3$+"[145]":NEXTX
112 C4$="":FORX=1TOMN-2:C4$=C4$+"":NEXTX:IFMN=2THENC4$=""
114 C5$="":UP$="":DN$="":GOSUB62:UP$="[145]":DN$=""
116 IFAN=1THEN144
118 IFAN=MNTHEN334
124 E=AN:MX=MN:GOTO206
126 PRINTCD$;" ***[158] LOADING LABELS ***"
128 OPEN8,8,8,"0:LABELS,S,R":GOSUB46
130 INPUT#8,NL$:GOSUB46
132 NL=VAL(NL$):IFNL=0THEN142
134 G=2:IFNL=18THENG=1
136 FORX=GTONL+1
138 INPUT#8,L6$(X),L1$(X),L2$(X),L3$(X),L4$(X),L5$(X)
140 GOSUB46:NEXTX
142 CLOSE8:MN=NL+2:GOSUB312:GOTO104
144 IFNL<>17THEN154
146 PRINT"[147]";B$;B$;"YOU ARE AT THE MAXIMUM # OF LABELS."
148 PRINT"YOU MUST NOW DELETE AN EXISTING LABEL"
150 PRINT"BEFORE YOU CAN CREATE A NEW LABEL."
152 FORT=1TO6000:NEXTT:GOTO106
154 PRINTPL$"":RE$=""
156 FORX=1TO5:PRINT" [155] [146]":NEXTX
158 FORF=1TO5
160 PRINT"";B$;B$;"[158]ENTER LINE #[154]";F;"[158]:":PRINTBL$
162 PRINT"[155] ^ ^[145][145][145]"
164 GOSUB26:NN$(F)=AN$
166 PRINT"":FORX=1TOF:PRINT"";:NEXTX:PRINT
168 PRINT" [155] [145]":PRINT" [155]";NN$(F)
170 IFCJ=1THENCJ=0:GOTO174
172 NEXTF
174 PRINT"";C$;C$;"[158]DO YOU WISH TO MAKE CHANGES? "Y$;
176 GETAN$:IFAN$=""THEN176
178 IFAN$="Y"THENPRINT" "AN$:GOTO184
180 IFAN$="N"THENPRINT" "AN$:GOTO194
182 GOTO176
184 PRINT"[158]ENTER LINE# (1-5[158]) TO CHANGE."
186 GETAN$:IFAN$=""THEN186
188 IFVAL(AN$)>5THEN186
190 IFVAL(AN$)<1THEN186
192 F=VAL(AN$):PRINT"[145][145][145]"BL$:PRINT""BL$:CJ=1:GOTO160
194 PRINT"[158]ENTER A TITLE FOR THIS LABEL:"
196 GOSUB26:IFAN$=""THENAN$="?"
198 NN$(6)=" "+AN$+" ":LS$="S"
200 SL$(MN+1)=SL$(MN)
202 L6$(MN)=NN$(6):L1$(MN)=NN$(1):L2$(MN)=NN$(2):L3$(MN)=NN$(3):L4$(MN)=NN$(4)
204 L5$(MN)=NN$(5):SL$(MN)=L6$(MN):MN=MN+1:NL=NL+1:GOTO106
206 PRINTPL$""
208 PRINTLJ$:PRINT" [155]";L1$(E)
210 PRINTLJ$:PRINT" [155]";L2$(E)
212 PRINTLJ$:PRINT" [155]";L3$(E)
214 PRINTLJ$:PRINT" [155]";L4$(E)
216 PRINTLJ$:PRINT" [155]";L5$(E)
218 PRINT:AN=1
220 SL$(1)=" PRINT THIS LABEL NOW "
222 SL$(2)=" PRINT ALIGNMENT PATTERN[160]"
224 SL$(3)=" PRINT A SPECIFIC QUANTITY[160]"
226 SL$(4)=" DELETE THIS LABEL[160]"
228 SL$(5)=" RETURN TO LABEL MENU[160]"
230 MN=5:C3$="[145][145][145][145][145][145][145][145][145]":C4$=C$:C5$=B$+C$:GOSUB60
232 IFAN=1THENGOSUB274:GOTO206
234 IFAN=2THENGOSUB288:GOTO206
236 IFAN=3THEN242
238 IFAN=4THEN296
240 IFAN=5THENMN=MX:GOSUB312:GOTO106
242 PY=5:GOTO316
244 INPUT"[158] PRINT LABEL HOW MANY TIMES [157][157][157][157][157][157][157][157]";QT
246 IFQT<1ORQT>99THENPRINT"[145][145][145][145][145][145][145]":GOTO242
248 FORX=1TOQT:GOSUB274:NEXTX:GOTO206
250 PRINTCD$;" *** [158]SAVING LABELS ***":XL=2
252 OPEN8,8,8,"@0:LABELS,S,W":GOSUB46
254 NL$=STR$(NL)
256 PRINT#8,NL$
258 FORX=2TONL+1
260 PRINT#8,Q$+L6$(X)+Q$
262 PRINT#8,Q$+L1$(X)+Q$
264 PRINT#8,Q$+L2$(X)+Q$
266 PRINT#8,Q$+L3$(X)+Q$
268 PRINT#8,Q$+L4$(X)+Q$
270 PRINT#8,Q$+L5$(X)+Q$
272 GOSUB46:NEXTX:CLOSE8:RETURN
274 PY=3:GOTO316
276 PRINT#4,L1$(E)
278 PRINT#4,L2$(E)
280 PRINT#4,L3$(E)
282 PRINT#4,L4$(E)
284 PRINT#4,L5$(E)
286 PRINT#4:RETURN
288 PY=4:GOTO316
290 PRINT#4,"**********************************"
292 FORX=1TO3:PRINT#4,"* *":NEXTX
294 PRINT#4,"**********************************":PRINT#4:RETURN
296 PRINT"[158] PROCEED WITH[160]DELETEING [158]LABEL? "Y$"[145][145]"
298 GETAN$:IFAN$=""THEN298
300 IFAN$="N"THEN206
302 IFAN$="Y"THEN306
304 GOTO298
306 FORX=ETOMX:L6$(X)=L6$(X+1):L1$(X)=L1$(X+1):L2$(X)=L2$(X+1):L3$(X)=L3$(X+1)
308 L4$(X)=L4$(X+1):L5$(X)=L5$(X+1):NEXTX
310 NL=NL-1:MN=MX-1:LS$="S":GOSUB312:GOTO106
312 SL$(1)=" CREATE A NEW LABEL ":FORX=2TONL+1:SL$(X)=L6$(X):NEXTX
314 SL$(MN)=" RETURN TO ENTRY MENU ":RETURN
316 IFPC=1THEN332
320 PRINTCD$"[154]PLEASE BE SURE YOUR PRINTER IS TURNED ON[146]"
322 PRINT"[158] PRESS "R$" TO PROCEED,"
324 PRINT"[158] OR PRESS 'C[158]' TO CANCEL PRINTING"
326 GETAN$:IFAN$=CHR$(13)THENPC=1:GOTO332
328 IFAN$="C"THEN206
330 GOTO326
332 ONPY-2GOTO276,290,244
334 IFLS$="S"THENGOSUB250
336 CLOSE4:PRINT"[147] ***[158] ONE MOMENT PLEASE ***"
338 PRINT"[144]LOAD"CHR$(34)"MENU";
340 PRINTCHR$(34)",8";
342 POKE198,5:POKE631,13:POKE632,82:POKE633,85:POKE634,78:POKE635,13:END